Hromada proměnných (Heap), alokace a dealokace paměti v IDL, ukazatele

IDL ve skutečnosti vytváří všechny proměnné na hromadě, jejich identifikátory však představují přímé odkazy. O alokaci a dealokaci paměti se v pozadí stará manažer hromady. Přiřazením nového obsahu do proměnné se zároveň vyhradí potřebné místo v paměti a případně se uvolní původní, nyní již nepotřebné. To se samozřejmě neděje, pokud přiřazujeme jen do části proměnné (do určité položky struktury, do podmnožiny buněk pole).

Funkce Temporary(P) poskytne obsah proměnné P v parametru, po té paměť alokovanou proměnné P uvolní a její identifikátor se stane nedefinovaným. Takto obvykle uvolňujeme již nepotřebná data, která zabírají hodně místa v paměti.

;příklad - G a H jsou velká pole

 G=0  ;radikální zmenšení alokované paměti pro G, proměnná G je stále definována>
 x=Total(Temporary(H)) ;při posledním použití dealokace paměti H

Práce s ukazateli

Používáme-li ukazatele, závisí alokace a dealokace částečně na nás. Proměnné na hromadě musíme umět vytvořit a uschovat odkazy na ně, musíme umět testovat platnost těchto odkazů a s jejich pomocí pracovat s obsahem proměnných. Nakonec musíme umět proměnné na hromadě zrušit, včetně těch, na které se odkazy nedopatřením ztratily. Následující body shrnují používané funkce a procedury a uvádějí příklady:

• výpis stavu hromady a zjištění datových typů proměnných, na které ukazatele vedou - Help, /heap
• výpis velikosti volné paměti - Help, /mem
• vytvoření nové proměnné na hromadě a generování ukazatele - funkce Ptr_new()
• vytvoření nové proměnné na hromadě z kopie dané proměnné, přiřazení ukazatele

  ;příklad - nový ukazatel na kopii pole 2x3
  pole=Bytarr(2,3)
  ppole=Ptr_new(pole)
  

• vytvoření nového ukazatele na proměnnou bez kopírování jejího obsahu, původní přímý identifikátor se tím stane nedefinovaný

  ;příklad - nový ukazatel na pole 2x3
  pole=Bytarr(2,3)
  ppole=Ptr_new(pole, /no_copy)
  

• vytvoření nového ukazatele na nedefinovanou proměnnou a jeho použití

  ;příklad - nový ukazatel na nedefinovanou proměnnou
  ppole=Ptr_new(/allocate_heap)
  *ppole=Bytarr(1000)
  ;příklad 2 - obdobně pracují příkazy 
  ; (je-li A nedefinovaná proměnná, jinak po prvním příkazu ukazuje qpole na kopii A)
  qpole=Ptr_new(A)
  *qpole=Dblarr(10,20)
  

• vytvoření neplatného (null) ukazatele

  ;příklad - null ukazatel
  ppole=Ptr_new()
  

• použití ukazatele - dereference

  ;příklad - dereference při čtení hodnoty
  a=*ppole(0,0)
  print, *ppole
  

  ;příklad - dereference v přiřazení
  (*ppole)(0,*)=Bindgen(3)
  *ppole=Replicate(255, 2,3)
  

  ;příklad - dereference null ukazatele je neplatná
  ptrnull=Ptr_new()
  *ptrnull=Strarr(10) ;za běhu způsobí chybu
  

• vytvoření pole ukazatelů - funkce Ptr_arr(D1, D2, ... Dn)
• vytvoření pole ukazatelů null

  ;příklad - práce s polem ukazatelů
  xpole=Ptrarr(10)
  xpole(0)=Ptr_new(Indgen(20))
  Plot, *xpole(0)
  (*xpole(0))(0:2)=[3, 4, 5]
  *xpole(1)=10.5 ; dereference null ukazatele, za běhu způsobí chybu
  

• vytvoření pole ukazatelů na nedefinované proměnné - lze dereferovat

  ;příklad 2 - práce s polem ukazatelů
  xpole=Ptrarr(10, /allocate_heap)
  *xpole(0)=Indgen(20)
  Plot, *xpole(0)
  Print, N_elements(*xpole(4))
  *xpole(9)=0
  

• zrušení ukazatelů a uvolnění paměti - procedura Ptr_free, její parametry (ukazatele) získají hodnotu null. Ptr_free není rekurzivní, náhradou lze užít proceduru Heap_free (viz dále).

  ;příklad  - zrušení proměnných *ppole a *xpole(0) až *xpole(9)
  Ptr_free, ppole, xpole  
  

• testování platnosti ukazatele a obnovení ztracených odkazů funkce Ptr_valid()
• testování platnosti ukazatele

  ;test platnosti ukazatele ppole
  if Ptr_valid(ppole) then ... 
  ;vytvoření seznamu indexů platných ukazatelů v poli xpole
  ii=Where(Ptr_valid(xpole), cii)  
  

• vytvoření seznamu všech proměnných na hromadě včetně těch, na které neukazuje žádný ukazatel

  ;seznam všech proměnných na hromadě 
  u=Ptr_valid()
  ;zrušení všech proměnných na hromadě (nerekurzivní, nedoporučuje se)
  Ptr_free, Ptr_valid()
  

• obnovení ztraceného odkazu na proměnnou na hromadě (nutno znát její číslo - viz Help, /heap)

  ;vytvoření proměnné a ukazatele
  t=Ptr_new([0,1,2,1,0])
  ;vytiskneme číslo proměnné na hromadě a obsah proměnné
  Print, t, *t
  ...
  ;ztracení ukazatele, pole stále zůstává na hromadě
  t=200
  ...
  ;obnovení ukazatele na pole v hromadě, víme-li, že jde o proměnnou hromady číslo 1
  t=Ptr_valid(1, /cast)
  

• uvolnění paměti všech ztracených proměnných hromady - procedura Heap_GC. Při jejím volání manažer hromady testuje, zda pro každou proměnnou na hromadě existuje platný odkaz tím, že prochází veškeré proměnné včetně common bloků a uživatelských hodnot widgetů a hledá v nich ukazatele. Proměnné se ztracenými odkazy (nelze pro ně najít platný ukazatel) zruší. Tato procedura je časově náročná, a proto se snažíme ztráty odkazů vyvarovat a správně užívat Ptr_free.

  ;vyčištění paměti
  Heap_GC, /ptr
  

• rekurzivní uvolnění paměti od zadaného ukazatele - procedura Heap_free. Tato procedura rekurzivně uvolňuje všechny proměnné hromady odkazované vstupním parametrem - prochází vstupní proměnnou včetně buněk všech polí a položek struktur. Narazí-li na platný ukazatel, označí proměnnou hromady k uvolnění a rekurzivně postupuje dále. Takto jsou nalezeny všechny přímé i nepřímé odkazy a cestou zpět jsou proměnné uvolněny a odkazy zrušeny voláním Ptr_free.

  ;vytvoření složité struktury s odkazy
  y={a:0, b:Ptr_new(Indgen(100))}
  X={Temporary(y), f:Ptrarr(2)}
  X.f(0)=Ptr_new(Fltarr(100,100))
  X.f(1)=Ptr_new(Ptr_new(Strarr(500)))
  ...
  ;řízené vyčištění paměti obsazené proměnnými hromady s odkazy v X
  Heap_free, X,  /ptr
  

;příklad - struktura se skalárem, polem 1x10 a obecným typem dat
X={a: 1L, b:Fltarr(10), c:Ptr_new(/allocate_heap)}    
;do položky c uložíme pole 2x3
*X.c=Dblarr(2,3)}
...
;do položky c uložíme pole 1x5
*X.c=Intarr(5)}